我的超低成本通讯模块

sio2 · 发表于 2009-5-8 16:16:46

用在魏讯数码（http://store.taobao.com/shop/view_shop.htm?shop_nick=momo_wen2008）购买的24L01PB模块，加上一个89C2051单片机，呵呵，单片机也是在淘宝上淘的，拆机件1.5元一个，一口气买了60个，要不对不起十几元的快递费 :)

(原文件名:收发模块.JPG)
实验时收发双方都采用相同的电路
发送方程序如下：
org 0000H
AJMP START

;延时1/4s子程序
YANSHI1S: MOV R7,#250
YANSHI1S1: MOV R6,#250
YANSHI1S2: NOP
NOP
DJNZ R6,YANSHI1S2
DJNZ R7,YANSHI1S1
RET

;将58开始的单或多字节（字节数在R3中）写入芯片
XIENB: MOV R0,#58H
CLR P1.7 ;SCN变低
XIE00: ACALL XIE1B
INC R0
DJNZ R3,XIE00
SETB P1.7
RET

;;将R0所指1单元按SPI时序写入模块,调用该子程序前，应将CSN线变低
;单次或多次调用完成后将CSN线变高
XIE1B: MOV R2,#8
MOV A,@R0
XIE1B1: RLC A
MOV P1.5,C ;数据送上MOSI线
SETB P1.4 ;数据移入模块
CLR P1.4
DJNZ R2,XIE1B1
RET

;读芯片状态字将芯片状态字读到5FH
DUZT: MOV R2,#8
SETB P1.5
CLR P1.7 ;CSN变低，
DUZT1: SETB P1.4 ;时钟上升
MOV C,P1.3 ;读入MISO线上的数据
MOV A,5FH
RLC A ;数据移入5FH寄存器
MOV 5FH,A
CLR P1.4
DJNZ R2,DUZT1
SETB P1.7 ;CSN变高，完成一次命令
RET

START: MOV P1,#0AFH ;模块待机
MOV 58H,#20H ;准备写0寄存器
MOV 59H,#0EH ;上电，发射模式
MOV R3,#02H
ACALL XIENB
MOV 58H,#21H ;01寄存器
MOV 59H,#03H ;0，1通道允许自动应答
MOV R3,#02H
ACALL XIENB
MOV 58H,#22H ;02
MOV 59H,#03H
MOV R3,#02H
ACALL XIENB
MOV 58H,#23H ;03寄存器
MOV 59H,#03H ;5字节地址宽带
MOV R3,#02H
ACALL XIENB
MOV 58H,#24H ;04
MOV 59H,#14H ;重发等待500uS，重发4次,1A则重发10次，在206c处
MOV R3,#02H
ACALL XIENB
MOV 58H,#25H ;05寄存器
MOV 59H,#07H ;射频频率(汇编后在2076处）
MOV R3,#02H
ACALL XIENB
MOV 58H,#26H ;06
MOV 59H,#27H ;07为1M传输速率，0dB增益，27则为250k传输速率
MOV R3,#02H
ACALL XIENB
MOV 58H,#27H ;07
MOV 59H,#70H ;清模块内中断
MOV R3,#02H
ACALL XIENB
MOV 58H,#2AH ;0A寄存器(通道0）
MOV 59H,#02H ;配置地址
MOV 5AH,#3AH
MOV 5BH,#39H
MOV 5CH,#38H
MOV 5DH,#37H
MOV R3,#06H
ACALL XIENB
MOV 58H,#30H ;10寄存器
MOV R3,#06H ;发送地址
ACALL XIENB
MOV 58H,#2BH ;0B寄存器（通道1）
MOV 59H,#01H ;本机地址
MOV R3,#06H
ACALL XIENB
MOV 58H,#31H ;11寄存器
MOV 59H,#10H ;0通道有效数据宽带16字节
MOV R3,#02H
ACALL XIENB
MOV 58H,#32H ;12寄存器
MOV 59H,#10H ;1通道有效数据宽度16字节
MOV R3,#02H
ACALL XIENB
XIEFS: MOV 58H,#0A0H ;写发送数据到芯片
MOV R0,#58H
MOV R3,#10H
CLR P1.7
ACALL XIE1B
MOV R0,#70H
XIEXUN: ACALL XIE1B
INC R0
DJNZ R3,XIEXUN
SETB P1.7
SETB P1.6 ;启动发射
MOV R7,#5
DJNZ R7,$
CLR P1.6
JB P3.2,$
cpl p1.0
ACALL DUZT ;读状态寄存器
MOV 58H,#27H ;07
MOV 59H,#70H ;清中断
MOV R3,#02H
ACALL XIENB
MOV 58H,#0E1H ;清模块发送缓冲区
MOV R3,#01H
ACALL XIENB
ACALL YANSHI1S
SJMP XIEFS

end

接收端程序：

org 0000H
AJMP START

org 0003H
AJMP EXINT0

;延时1/4s子程序
YANSHI1S: MOV R7,#250
YANSHI1S1: MOV R6,#250
YANSHI1S2: NOP
NOP
DJNZ R6,YANSHI1S2
DJNZ R7,YANSHI1S1
RET

;将58开始的单或多字节（字节数在R3中）写入芯片
XIENB: MOV R0,#58H
CLR P1.7 ;SCN变低
XIE00: ACALL XIE1B
INC R0
DJNZ R3,XIE00
SETB P1.7
RET

;;将R0所指1单元按SPI时序写入模块,调用该子程序前，应将CSN线变低
;单次或多次调用完成后将CSN线变高
XIE1B: MOV R2,#8
MOV A,@R0
XIE1B1: RLC A
MOV P1.5,C ;数据送上MOSI线
SETB P1.4 ;数据移入模块
CLR P1.4
DJNZ R2,XIE1B1
RET

;按SPI时序读模块一字节入单片机R0所指单元,调用该子程序前，应将CSN线变低
;单次或多次调用完成后将CSN线变高
DU1B: MOV R2,#8
DU1B1: SETB P1.4
MOV C,P1.3
RLC A
CLR P1.4
DJNZ R2,DU1B1
MOV @R0,A
RET

;按SPI时序读模块接收缓冲区数据入单片机R0所指单元，字节数在R3中
DUNB: PUSH 00H
MOV 58H,#61H ;写一字节命令
MOV R0,#58H
CLR P1.7
ACALL XIE1B
POP 00H ;R0指向接收缓冲区首地址
DUXUN: ACALL DU1B
INC R0
DJNZ R3,DUXUN
SETB P1.7
RET

;读芯片状态字将芯片状态字读到5FH
DUZT: MOV R2,#8
SETB P1.5 ;输入芯片1
CLR P1.7 ;CSN变低，
DUZT1: SETB P1.4 ;时钟上升
MOV C,P1.3 ;读入MISO线上的数据
MOV A,5FH
RLC A ;数据移入5FH寄存器
MOV 5FH,A
CLR P1.4
DJNZ R2,DUZT1
SETB P1.7 ;CSN变高，完成一次命令
RET

START: MOV P1,#0AFH ;模块待机
SETB 0A8H ;允许外部中断0
CLR 88H ;电平触发
SETB 0B8H ;高优先级
SETB 0AFH ;CPU开中断

MOV 58H,#20H ;准备写0寄存器
MOV 59H,#0FH ;上电，接收模式（发射时，设置为0EH）
MOV R3,#02H
ACALL XIENB
MOV 58H,#21H ;01寄存器
MOV 59H,#03H ;0，1通道允许自动应答
MOV R3,#02H
ACALL XIENB
MOV 58H,#22H ;02
MOV 59H,#03H ;允许0，1通道接收
MOV R3,#02H
ACALL XIENB
MOV 58H,#23H ;03寄存器
MOV 59H,#03H ;5字节地址宽带
MOV R3,#02H
ACALL XIENB
MOV 58H,#24H ;04
MOV 59H,#14H ;重发等待500uS，重发4次
MOV R3,#02H
ACALL XIENB
MOV 58H,#25H ;05寄存器
MOV 59H,#07H ;射频频率
MOV R3,#02H
ACALL XIENB
MOV 58H,#26H ;06
MOV 59H,#27H ;设置为07为1M传输速率，0dB增益(若为27，则是250kpbs，0dB）
MOV R3,#02H
ACALL XIENB
MOV 58H,#27H ;07
MOV 59H,#70H ;清模块内中断
MOV R3,#02H
ACALL XIENB
MOV 58H,#2AH ;0A寄存器(通道0）
MOV 59H,#01H ;配置地址（对方地址）
MOV 5AH,#3AH
MOV 5BH,#39H
MOV 5CH,#38H
MOV 5DH,#37H
MOV R3,#06H
ACALL XIENB
MOV 58H,#30H ;10寄存器
MOV R3,#06H ;发送地址
ACALL XIENB
MOV 58H,#2BH ;0B寄存器（通道1）
MOV 59H,#02H ;本机地址
MOV R3,#06H
ACALL XIENB
MOV 58H,#31H ;11寄存器
MOV 59H,#10H ;0通道有效数据宽带16字节
MOV R3,#02H
ACALL XIENB
MOV 58H,#32H ;12寄存器
MOV 59H,#10H ;1通道有效数据宽度16字节
MOV R3,#02H
ACALL XIENB
SETB P1.6 ;启动接收
HALT: SJMP HALT

EXINT0: PUSH ACC
PUSH PSW
ACALL DUZT ;读状态寄存器
MOV 58H,#27H ;07
MOV 59H,#70H ;清中断
MOV R3,#02H
ACALL XIENB
MOV R0,#60H ;读接收数据到60H到6FH
MOV R3,#10H
ACALL DUNB
CPL P1.0
FANHUI: POP PSW
POP ACC
RETI

end

这个实验的通讯距离在楼道内没有阻挡的情况下可以达到30m（我这里的这个楼道只有30m，没试其他空旷地）
接收端的电流如果一直让模块处于接收状态会有15.6mA
在后续的实验中将接收端的工作状态改为每100mS接收5mS，平时让CPU和24L01都处在待机状态。而发送端一直不停的发送信号。这样，接收端完全能在5mS的窗口期内完整的收到一个数据包。这时接收端的平均电流只有1mA了。

155107149 · 发表于 2009-5-8 17:15:44

不错，楼主用汇编果然厉害，慢慢看看

rengo · 发表于 2009-5-8 17:31:50

1M传输速率，0dB增益 30M,够猛

sio2 · 发表于 2009-5-8 18:07:20

但2.4G的穿墙能力不行，我在家里试验，穿一堵20cm厚的砖混结构的墙没任何问题，能在两间屋的任何角落通讯，但穿两堵墙就要找地方才能收到信号了。
24L01+这个模块最高只有0dB增益。如果用阿莫的BK2411这个模块，其接收灵敏度更高，发射功率也有5dB，估计穿两堵墙没任何问题。

Momo · 发表于 2009-5-8 18:37:51

多谢sio2的分享。期待更多的作品！

ndust · 发表于 2009-5-8 20:28:18

tage · 发表于 2009-5-8 21:09:01

不错哦。

whitelight · 发表于 2009-5-8 21:16:56

看来得研究汇编了

ztom · 发表于 2009-5-8 21:17:22

百花争鸣，支持。

Momo · 发表于 2009-5-8 21:20:35

sio2兄是一位高手，在我的“游说”下开始进军AVR，呵呵！

pcs3 · 发表于 2009-5-8 21:32:01

51的汇编看着就是舒服~~想起了刚学单片机那会

longquan · 发表于 2009-5-8 23:02:34

不错

sio2 · 发表于 2009-5-8 23:24:05

就这个试验来说，汇编程序中有很多语句是可以省掉不用的，比如进入中断服务程序后的现场保护，完全没必要。不过由于自己长期养成的习惯，也给写出来了。要细研究的话还可以去掉一些语句。想想反正是做试验，也就将就了。

m-aaaa · 发表于 2009-5-9 11:13:43

呵呵,不错

rf_mj · 发表于 2009-5-17 21:34:58

wxmk12 你们公司做的模块才10多m，太差了吧，楼主这个可以达到30m以上哦，请注意是楼道的最长的长度，要楼道长点估计距离还可更远。

sio2 · 发表于 2009-5-17 21:36:33

估计15楼的朋友是在水下调试的吧，说笑一下。请15楼的朋友把你调试的详细过程说说，你的试验电路是怎样的？大家帮你分析一下看问题在哪儿。其实通讯距离是模块生产的过程中就已经决定了的了。我是采用的现成的模块，在15楼的朋友该不会说是自己用某某芯片来自己设计射频部分的线路板自己焊接的吧。如果是，那能达到30m就很不错了。
光在这儿丢下个“你花了多少多少时间，才怎么样，都是什么什么的”你不觉的说话太不负责任了吗？

sio2 · 发表于 2009-5-17 21:43:09

还有试验的程序也是至关重要的，模块如果没有设置好也是不肯能有好的通讯效果的。

powerSTM · 发表于 2009-5-17 22:02:34

Mark

sio2 · 发表于 2009-5-17 22:04:34

在程序上，模块如果没有设置好也是不可能有好的通讯效果的。如接收或发送数据以后引起的中断要及时清除，接收到的数据后要及时读出，否则把FIFO占满了也是收不到数据的。等等。数据手册上讲得很明白，请15楼的朋友仔细了解了数据手册再做试验。

hecat · 发表于 2009-5-21 01:09:04

Mark!

longquan · 发表于 2009-5-21 08:03:40

汇编的真精简

af00 · 发表于 2009-5-21 11:57:58

很有亲切感，顶了

shotstar · 发表于 2009-5-21 12:18:41

不错的东西成本是比较低，模块也自己做就好了。

sio2 · 发表于 2009-5-21 15:43:47

这就是当时做实验的实物，好在我还没有拆了它，要不就照不下这个图了。

(原文件名:100_1177.JPG)

(原文件名:100_1179.JPG)

(原文件名:100_1186.JPG)

在当时一系列的实验中，为了验证那16个字节数据的准确性，我又在P1.1上加了个LED，在中断程序中判断所接收的数据如果是预定的就让P1.1也反向一下。
如果有朋友想重复这个实验，那么上面的两个程序完全可以直接采用，复制到Keil里编译好后用编程器写到89C2051里就行了。
细心的朋友可能会看到汇编程序的注释里有“(汇编后在2076处）”字样，这是我用这个程序在其他51开发板上实验时随手加上去的。并不影响这次的实验。

whuctx · 发表于 2009-5-21 17:11:31

佩服楼主，向楼主学习

hejunbok · 发表于 2009-5-21 19:45:50

汇编不会编啊
痛苦

plank · 发表于 2009-5-21 19:55:10

这么多人喜欢玩2401+MCU，而且是51。Nordic本身就推出了MCU+TR的方案，24el，还带AD，多好的东东啊。国内现在的卖这个模块的便宜的很，当年我最开始买这个的时候可是2XX一个

gzhuli · 发表于 2009-5-21 20:44:35

24E1有24L01+2051便宜么？

liuhengming · 发表于 2009-5-22 01:28:56

你是买了60个了,都让你抢光咯

Momo · 发表于 2009-5-22 09:13:44

刘兄这是标准的搭棚啊！

qji850 · 发表于 2009-5-22 09:35:03

mark

sio2 · 发表于 2009-5-22 10:58:36

呵呵，回Momo：实验时先这样简单的把电路搭上，方便。等要做一个东西的时候再设计一个板子，并配上一个好看的外壳。

kenpow · 发表于 2009-5-23 11:55:45

(原文件名:34.jpg)

30米楼道？？？而且不加增益天线，我都很怀疑你是不是托。
楼道干扰那么大  你还能达到30米？？？
你用过无线吗？2.4G 的频段是共用的，那干扰很多，况且还在楼道
我用讯通的NRF24L01  +5DB 增益天线在空旷马路上才达到23米左右，在室内只有10几米

sio2 · 发表于 2009-5-23 13:05:59

实践是检验真理的唯一标准，我已经试验过了，我可以负责人的告诉大家，我的试验结果是正却的，没有任何水分。有兴趣的朋友可以重复这个试验。
鉴于影响无线通讯距离的因素太多，模块自身的质量、试验环境、软件的设计等等，我只能说我这次试验是让自己满意的。
至于35楼，你说这些有意义吗？你想表达一个什么目的？你的试验不理想该自己去找找原因，如过想让人帮忙也不该是这个态度。
我有理由怀疑你就是被Momo敬告的那位换了个马甲又来捣乱来了，要不怎么跑进论坛来第一篇帖子就是这样。

zhwm3064 · 发表于 2009-5-23 13:21:20

反射

kenpow · 发表于 2009-5-23 17:23:59

LZ 太浮躁了先做下实验在说了

sio2 · 发表于 2009-5-23 19:19:26

建议大家看看这个帖子，kenpow的语调和wxmk12这家伙的是何等相似
http://www.ourdev.cn/bbs/bbs_content.jsp?bbs_sn=3359691&bbs_page_no=1&bbs_id=3050

xoxo · 发表于 2009-5-25 14:08:15

这个RF多少钱一个呀

sio2 · 发表于 2009-5-25 23:28:10

XOXO同志，很严重的对你说哦，两个XO都喝得起的同志还要问多少钱一个嗦。

上面几句话纯属想来个四川式的幽默哈，请大家见谅一哈。
具体价格请登陆 http://store.taobao.com/shop/view_shop.htm?shop_nick=momo_wen2008
Momo的淘宝店自己看去。

sctwp · 发表于 2009-5-26 06:51:59

支持LZ

hjian508 · 发表于 2009-5-26 20:51:47

支持

xoxo · 发表于 2009-5-29 15:03:21

看了一下，还不错！顶一下！

bingou · 发表于 2009-6-3 04:01:56

还有卖的吗，看看！

http://store.taobao.com/shop/view_shop.htm?shop_nick=momo_wen2008

czzhouyun · 发表于 2009-6-3 09:09:15

mark

guomip · 发表于 2009-6-3 17:57:04

貌似卖完了啊!!

sio2 · 发表于 2009-6-3 23:48:42

有可能真的卖完了，这么好的模块该多生产些才对，问问Momo，请Momo回答。

slshu · 发表于 2009-6-9 22:07:45

最近在忙RF无线通信套件,可能没空搞这些小玩意了
楼主这个模块可以用其他的代替吗?

psocfans · 发表于 2009-6-16 16:12:59

看着舒服

mikecn · 发表于 2009-6-16 16:49:59

店里什么也没有

Momo · 发表于 2009-6-27 23:23:24

刘兄，好久没出来灌水了噢，宝宝应该出世了吧，出来了一定要来报个喜啊。

sio2 · 发表于 2009-6-28 12:11:46

多谢Momo挂念，呵呵，我这几天忙惨了，17号生的一个六斤男孩，生下来时身体素质很好，医生给了10分的满分评价。现在母子平安。刚生的小孩子很难缠，搞得我这段时间严重睡眠不足，不过心里还是挺高兴的。

Momo · 发表于 2009-6-28 12:49:42

恭喜刘兄！

382383706 · 发表于 2009-6-29 19:14:58

好久没用汇编了

liyong110 · 发表于 2009-7-6 15:57:26

为什么我看不到头像呢

sio2 · 发表于 2009-7-8 08:28:43

我试验中用的模块又有消息了，http://store.taobao.com/shop/view_shop.htm?shop_nick=%ca%ae%d7%d6%bd%d6%cd%b7_%c3%d4%e3%af
我无意为任何商家做说客，我当初用了魏讯的这个模块觉得好，希望大家都试试，不会有遗憾的。
Momo已经将公司产品销售委托给了其同事，我感觉Momo不想卷入生意场那“低俗”的交往中，我在此擅自揣度Momo，望见谅！

z7926573 · 发表于 2009-7-8 09:16:03

mark

zhames · 发表于 2009-7-8 09:41:41

thx for your share ,learning...

tanguoyong · 发表于 2009-7-8 10:07:37

好东西

tanguoyong · 发表于 2009-7-8 10:07:43

好东西

tanguoyong · 发表于 2009-7-8 10:08:06

好东西

hailiyidishui · 发表于 2009-7-26 06:41:46

mark

isbit · 发表于 2009-7-30 10:21:56

如果有跳频就好了

qiuhuawei · 发表于 2009-7-30 10:26:00

好资料

af00 · 发表于 2009-7-30 11:33:27

谢谢，顶

a5e6 · 发表于 2009-8-11 11:22:37

真了不起，我家里还摆着大学时做的机器人，是AT89S51搞的，8块钱一片哦。在长沙买得真贵。

wujiang0925 · 发表于 2009-8-13 10:35:02

看看，挺感兴趣的。

shaoyidong · 发表于 2009-8-18 06:38:22

mark

wajlh · 发表于 2009-8-18 07:13:06

make

21006091 · 发表于 2009-8-18 08:48:46

mark

m32112 · 发表于 2009-8-18 19:10:27

支持下

zqy517 · 发表于 2009-9-3 11:46:49

支持LZ 但是得估计下成本是？超低？低到什么程度呢？

qhshilin · 发表于 2009-9-15 16:26:57

呵呵楼上的太厉害了，呵呵、。

PolarLights · 发表于 2009-9-15 17:28:49

马克一下

z7926573 · 发表于 2009-9-15 20:28:07

mark

zsl602 · 发表于 2009-9-21 10:57:36

好资料，收藏了！

laoygyj · 发表于 2009-9-21 14:05:37

master5888 · 发表于 2009-9-21 16:45:55

mark

lowwr · 发表于 2009-9-22 14:55:59

mark

bingeai · 发表于 2010-1-25 21:24:42

mark

D.lovers · 发表于 2010-1-25 22:01:30

mark

silvanesw · 发表于 2010-1-25 22:10:33

mmaarrkk...

rainbow · 发表于 2010-1-25 22:15:17

刚看了下,现在是20一片了.

sw821025 · 发表于 2010-1-28 17:24:07

好东东

aiyige · 发表于 2010-1-28 17:28:47

不错！！

litteworm · 发表于 2010-1-28 18:18:44

回复【88楼】rainbow 老陈
刚看了下,现在是20一片了.
-----------------------------------------------------------------------

额涨价了？

sunmy · 发表于 2010-2-6 13:36:09

ding!

hongyancl · 发表于 2010-2-6 13:54:32

回复【楼主位】sio2
-----------------------------------------------------------------------

huibain 功夫了得

zhuwei310600 · 发表于 2010-2-23 18:06:27

好东西

boy364100 · 发表于 2010-2-23 23:26:14

想买~MARK~

zldiy · 发表于 2010-2-24 08:19:30

不错。留个脚印

RF2010 · 发表于 2010-2-26 23:59:02

点击此处下载 ourdev_535488.pdf(文件大小:185K) (原文件名:无线数据通信汇总和选型参考.pdf)

sharp0 · 发表于 2010-5-22 16:02:46

mark!

format · 发表于 2010-5-22 16:41:04

服了，又是个达人~~~~

搭棚焊，还有贴片~~~晕死

http://item.taobao.com/auction/item_detail.htm?item_num_id=4298836530

大家可以考虑玩我的这个哈

lymum · 发表于 2010-6-2 17:35:26

强贴留名以后慢慢看

haowei236 · 发表于 2010-6-22 13:04:24

MARK

MWay · 发表于 2010-6-22 15:12:37

moreway.taobao.com无线模块全系列、无线开发套件、无线ARM开发套件、无线手持机

yu230 · 发表于 2010-6-22 18:41:09

通讯模块记号

yhdt · 发表于 2010-11-13 02:00:30

记下。。。不懂汇编。。呵呵...以后应该能用到

我的超低成本通讯模块

阿莫论坛20周年了！感谢大家的支持与爱护！！