请教一个关于SWI的问题

zengxy

在ATPCS条件下编译时，SWI是不是被当成一个函数调用来编译？这样的话R0~R3是作为传递参数的寄存器来用的，那进入SWI保存现场时应该不需要保存R0~R3吧？为什么我看网上好多例程都保存了，还有的只保存了R0~R3以及少量的几个别的寄存器而已，比如这个：


;/*
;*******************************************************************************************
;** 模 块 名：SWI.s
;** 功能描述：SWI异常处理函数
;** 创建日期：04-16-2007  by：CANopen
;** 修改日期：     by：
;*******************************************************************************************
;*/
    AREA SWI_Function, CODE, READONLY

    EXPORT SWI_Handler_Ex
    IMPORT SWI_Exception_Function

;T_bit EQU 0x20

SWI_Handler_Ex

    STMFD   sp!,  {r0-r3, r12, lr}    ;// STMDB,保护现场
    MOV     r1,  sp                   ;// 若SWI调用带参，将R1指向第一个参数
                 ;// 遵照ATPCS标准，第一个参数存于R0中
    MRS     r0,  spsr              
    STMFD   sp!,  {r0}                ;// spsr入栈
    LDR    r0,  [lr,#-4]             ;// 获取SWI指令码
    BIC    r0,  r0, #0xFF000000      ;// 获取SWI number

    ;// r0 now contains SWI number
    ;// r1 now contains pointer to stacked registers

    BL      SWI_Exception_Function       ;// 调用C编写的SWI处理函数
    LDMFD   sp!,  {r0}            
    MSR     spsr_cf,r0               ;// spsr出栈
    LDMFD   sp!,  {r0-r3, r12, pc}^   ;// 恢复现场

    END


不知道是我哪里理解错了，还请各位指点

dr2001

看你准备把SWI怎么用。

ATPCS下，编译器是把SWI是当普通函数处理的，都可以带返回值的。如果要当普通函数用，什么都不用保存。。。
但是要注意处理器模式。

如果要当中断那样用，就需要处理现场了。

SWI设计之初的想法是当函数用，我认为。

zengxy

如果我用C编程的话应该是完全取决于编译器了吧？就是当普通函数用？

如果我调用的时候是在C里面调用的，但是中断服务程序用汇编写呢？是不是应该保存除了R0~R3以外的寄存器？

另外您说的“注意处理器模式”具体指什么？能再具体一点吗？

谢谢

zengxy

还有，我贴的例子里的代码怎么解释呢？

dr2001

回复【2楼】zengxy  
-----------------------------------------------------------------------

对于ARM的RVCT系统，中断函数只要保护LR，切换到SYS/USR模式就行，解决SWI的重入问题。
函数按照AAPCS，是标准的C函数就行。

因为RVCT把SWI当普通函数处理，所以调用SWI的函数会允许SWI修改R0-R3/R12。
因为函数符合AAPCS，它保证进出时其余寄存器值不变。

你贴的代码，是SWI指令查表的问题。对ARM函数调用，有：
R0 Func(R0, R1, R2, R3, Stack...)，数字表示参数的保存位置。
但是Func == SWI(X)的时候，多一个SWI Number X。你需要有代码处理这个事情。

你贴的代码相当于
C语言里调用：_SWI(X)_ R0 Func(R0)。
但是处理的函数是R0 SWI_Handler(X, R0)：先根据X确认要调用哪个函数，然后把输入的R0装到那个函数中。

dr2001

贴一段没认真调试过的代码，可以参考一下。

支持SWI重入；SWI是普通函数，可以带参数/返回值的。
其实R12和SPSR可以不存。。。节约点堆栈，开关中断等行为也更好完成。


Code_SWI
;  SWI Exception Handler With Reentrant
        STMFD   SP!, {R12, LR}                  ;  Store Registers.
        MRS     R12, SPSR                       ;  Get   SPSR
        TST     R12, #0x20                      ;  Check Processor State [T Bit]
        STR     R12, [SP, #-8]!                 ;  Save  SPSR for Reentrant
        STMIB   SP, {LR}^                       ;  Save  USR/SYS Mode LR

        LDRNEH  LR, [LR, #-2]                   ;  Thumb State, Get SWI Instruction
        LDREQ   LR, [LR, #-4]                   ;  ARM   State, Get SWI Instruction
        LDR     R12, = Vect_SWI_Idx             ;  Get SWI Handler Function Address
        BICNE   LR, LR, #0xFF00                 ;  Thumb State, Get SWI Number
        BICEQ   LR, LR, #0xFF000000             ;  ARM   State, Get SWI Number
        LDR     R12, [R12, LR, LSL #2]          ;  Look UP Jump Table

        MSR     CPSR_c, #ARM_MODE_SYS
        BLX     R12                             ;  Call  SWI Handler Function
        MSR     CPSR_c, #ARM_MODE_SVC | I_BIT

        LDR     R12, [SP], #8                   ;  Restore SPSR
        LDMDB   SP, {LR}^                       ;  Restore USR/SYS Mode LR
        NOP
        MSR     SPSR_cxsf, R12
        LDMFD   SP!, {R12, PC}^                 ;  Restore Registers and Return