分享一段自己写的24C02外部存储器的读写汇编子程序-已通...

chaily

这几天研究IIC总线，重新按自己的思路写了这个24C02的读写程序，用于在自己的主程序中调用。24C02可用于对数据采集的掉电保存或者系统的设置的读取或保存，对于没有数据保存能力的MCU是有很大作用的。使用两个I/O口模拟IIC总线与24C02做数据通信，很多人总觉得汇编很复杂，其实优化过的汇编是很简洁的，直指硬件的时序操作，也很直观，汇编达人请指正一些不够完善的地方，也欢迎大家讨论～～  
分享一下汇编程序如下：

;数据写或读用A作为位载体，R2作为24c02位置字节地址，R3是写入或读出的内容
SDA EQU P2.0;定义24C02的串行数据线
SCL EQU P2.1;定义24C02的串行时钟线
ORG 0000H
AJMP START
ORG 0030H
START:MOV SP,#60H
MAIN:  ;放入需要的主程序
AJMP $


XIE:  ;写数据子程序，R2是要写入的24c02的字节位置地址，R3是要写入的内容
LCALL STAR;起始条件
MOV A,#10100000B;寻址24C02的总线硬件地址并使用写入命令
LCALL SDATA;传输数据A给24C02
MOV A,R2   ;确定要写入的字节位置地址
LCALL SDATA;传输数据A给24C02
MOV A,R3   ;把数据R3写入刚指定的字节地址
LCALL SDATA;传输数据A给24C02
;此处可在一页中(24C02一页为8字节，共32页)继续连续写入，注意一次不超过8个字节，字节地址自动+1，也可以不连续写
LCALL STOP;写入结束
LCALL CHULI ;提供2ms给24C02内部处理刚写入的数据，注意只有写完数据需要给24C02一定的处理时间
RET

DU:   ;读数据子程序，R2是要读的24c02的字节位置地址，读完后A传给R3
LCALL STAR;起始条件
MOV A,#10100000B;寻址24C02的总线硬件地址并使用写入命令(注意这里是写入命令)
LCALL SDATA;传输数据A给24C02
MOV A,R2   ;注意，这里是使24C02的字节地址指针变成R2的值，也就是确定要读取的字节位置地址
LCALL SDATA;传输数据A给24C02
LCALL STAR ;重复起始条件
MOV A,#10100001B;寻址24C02的总线硬件地址并使用读出命令(这里正式发起读命令)
LCALL SDATA;传输数据A给24C02
LCALL RDATA;从之前指定的字节地址中读出字节内容到A
LCALL STOP ;读取完毕(这里并没有连续读取，只能读一个字节，要多个字节连续读取，请自己在R2上做变址读取循环)
MOV R3,A  ;读出的字节传给R3
RET

STAR:SETB SDA ;起始条件子程序
SETB SCL
NOP
NOP
NOP
NOP
CLR SDA
NOP
NOP
NOP
NOP
RET

SDATA:MOV R0,#08H ;向24C02传输数据子程序
LOOP0:CLR SCL
RLC A
MOV SDA,C
NOP
NOP
SETB SCL
NOP
NOP
NOP
NOP
DJNZ R0,LOOP0
CLR SCL
NOP
SETB SDA
NOP
NOP
SETB SCL
REP:MOV C,SDA
JC REP
NOP
NOP
NOP
CLR SCL
NOP
NOP
RET

RDATA:MOV R0,#08H  ;从24C02读取数据子程序(读取一个字节以后不做应答)
LOOP1:SETB SCL
NOP
NOP
NOP
NOP
MOV C,SDA
RLC A
CLR SCL
NOP
NOP
NOP
NOP
DJNZ R0,LOOP1
SETB SCL
NOP
NOP
NOP
NOP
CLR SCL
RET

STOP:CLR SDA   ;结束条件
NOP
NOP
NOP
NOP
SETB SCL
NOP
NOP
NOP
NOP
SETB SDA
NOP
NOP
NOP
NOP
RET

CHULI: ;1999uS  ;这里是用于写完数据以后留给24C02的内部数据处理时间，2ms是一个非常保险的时间，最短需要1ms
    MOV R6,#04H
WR0:
    MOV R5,#0F8H
    DJNZ R5,$
    DJNZ R6,WR0
    RET
END

woshigeshuai

谢谢分享

xiaoya1945

响应一下Lz,我也贴段汇编 IIC EEPROM 的 程式，不过... 只能我自己使用了

1. 
   
2. ;;====================================================;;
   
3. ;; Random Read
   
4. Random_Read_Init:
   
5.         Disable_All_Interrupt                ;;在读写24C02操作中，关闭中断，以防出错
   
6.         LD        A,#0FH
   
7.         LD        (Time_Out),A               
   
8.         LDPCH        WRITE_WAIT
   
9.         CALL        WRITE_WAIT
   
10.         LDPCH        WRITE_WAIT
    
11.         CALL        WRITE_WAIT
    
12. Random_Read_Start:
    
13.        
    
14.         LD        A,#05H
    
15.         LD        (WATCH),A                ;;Reset WDT
    
16.         DEC        (Time_Out)
    
17.         LDPCH        Random_Read_TimeOut
    
18.         JZ        Random_Read_TimeOut
    
19.        
    
20.         LDPCH        IIC_START
    
21.         CALL        IIC_START
    
22. Send_Add_R_Command:
    
23.         LD        A,#Device_Add.N0        ;;发送器件地址和写命令
    
24.         AND        A,#Write_Command
    
25.         LD        (DATAL),A
    
26.         LD        A,#Device_Add.N1
    
27.         LD        (DATAH),A
    
28.         LDPCH        WRITE_BYTE                ;;写一个Byte到IIC BUS
    
29.         CALL        WRITE_BYTE
    
30.         LDPCH        Receive_ACK
    
31.         CALL        Receive_ACK
    
32.         AND        A,#0001B
    
33.         LDPCH        Random_Read_Start
    
34.         JNZ        Random_Read_Start
    
35.         LD        A,#Read_Word_Add.N0        ;;指定从器件从word Add读起
    
36.         LD        (DATAL),A
    
37.         LD        A,#Read_Word_Add.N1
    
38.         LD        (DATAH),A
    
39.        
    
40.         LDPCH        WRITE_BYTE
    
41.         CALL        WRITE_BYTE
    
42.         LDPCH        Receive_ACK
    
43.         CALL        Receive_ACK
    
44.         AND        A,#0001B
    
45.         LDPCH        Random_Read_Start
    
46.         JNZ        Random_Read_Start
    
47.        
    
48.         LDPCH        IIC_START
    
49.         CALL        IIC_START
    
50.        
    
51.         LD        A,#Device_Add.N0        ;;再次发送 从器件地址,并发送读命令
    
52.         OR        A,#Read_Command
    
53.         LD        (DATAL),A
    
54.         LD        A,#Device_Add.N1
    
55.         LD        (DATAH),A
    
56.         LDPCH        WRITE_BYTE
    
57.         CALL        WRITE_BYTE
    
58.         LDPCH        Receive_ACK
    
59.         CALL        Receive_ACK
    
60.         AND        A,#0001B
    
61.         LDPCH        Random_Read_Start
    
62.         JNZ        Random_Read_Start
    
63.        
    
64.         LDPCH        READ_BYTE
    
65.         CALL        READ_BYTE
    
66.        
    
67.         LDPCH        M_to_S_NoACK
    
68.         CALL        M_to_S_NoACK
    
69.        
    
70.         LDPCH        IIC_STOP
    
71.         CALL        IIC_STOP                ;;Random_Read 结束，读到的数据存放于DATAL和DATAH中
    
72. Random_Read_End:
    
73.         LD        A,(DATAL)                ;;读取到的数据给PB和PD，指示结果
    
74.         LD        (DATA_PB),A
    
75.         LD        A,(DATAH)
    
76.         LD        (DATA_PD),A
    
77.        
    
78.         LDPCH        Main_Loop
    
79.         JMP        Main_Loop
    
80. 
    
81. Random_Read_TimeOut:
    
82.         Enable_All_Interrupt
    
83.         LDPCH        Main_Loop
    
84.         JMP        Main_Loop
    
85.        
    
86.        

复制代码

chaily

xiaoya1945 发表于 2012-9-19 12:44
响应一下Lz,我也贴段汇编 IIC EEPROM 的 程式，不过... 只能我自己使用了 ...

啊。。。。这思路似乎和我的不打相同。。。没细看，，，能当作子程序嵌入到别的程序里面不？

xiaoya1945

chaily 发表于 2012-9-19 12:54
啊。。。。这思路似乎和我的不打相同。。。没细看，，，能当作子程序嵌入到别的程序里面不？ ...

这段程序是一个4Bit MCU的，24C02随机读的一段代码，所以说这个只能我自己使用了...

chaily

xiaoya1945 发表于 2012-9-19 13:04
这段程序是一个4Bit MCU的，24C02随机读的一段代码，所以说这个只能我自己使用了...  ...

还有4bit的MCU？？便宜不？介绍个型号吧～～

zjk

汇编的。。。真心没毅力看下去。。

风雨无阻88

做个记号