uCOSII移植到CortexM0上遇到的问题

bpengj3375

各位前辈好，我按照uCOSII移植到CortexM3的步骤，将uCOSII移植到CortexM0上，发现OS_CPU_A.ASM 中的个别指令M0不支持，
比如CBZ，如何用M0自己的指令替代这些呢，谢谢指导！

无法辨认的指令有：
   CBZ     R0, OS_CPU_PendSVHandler_nosave                     ; Skip register save the first time
   STM     R0, {R4-R11}
   POP     {R14}                                                   ;此处编译器提示应该用R0到R7
   LDM     R0, {R4-R11}                                        ; Restore r4-11 from new process stack
   ORR     LR, LR, #0x04                                       ; Ensure exception return uses process stack

armstrong

1.    
   
2.     RSEG    .text:CODE:NOROOT(2)
   
3.     THUMB
   
4. PendSV_Handler
   
5.     CPSID   I                                   ; Prevent interruption during context switch
   
6.     MRS     R0, PSP                             ; PSP is process stack pointer
   
7. 
   
8.     CMP     R0, #0
   
9.     BEQ     __nosave_regs                       ; equivalent code to CBZ from M3 arch to M0 arch
   
10.     ; Except that it does not change the condition code flags
    
11. 
    
12.     SUBS    R0, R0, #0x20                       ; Save remaining regs r4-r11 on process stack
    
13.     LDR     R1, =OSTCBCur                       ; OSTCBCur->OSTCBStkPtr = SP;
    
14.     LDR     R1, [R1]
    
15.     STR     R0, [R1]                            ; R0 is SP of process being switched out
    
16.    
    
17.     STM     R0!, {R4-R7}                        ; Store R4-R7(Low Registers) on process stack
    
18.     MOV     R4, R8                              ; Move R8-R11 values to R4-R7 registers.
    
19.     MOV     R5, R9
    
20.     MOV     R6, R10
    
21.     MOV     R7, R11
    
22.     STM     R0!, {R4-R7}                        ; Store R8-R11(High Registers) on process stack
    
23. 
    
24.     ; At this point, entire context of process has been saved
    
25. __nosave_regs
    
26.     LDR     R0, =OSPrioCur                      ; OSPrioCur = OSPrioHighRdy;
    
27.     LDR     R1, =OSPrioHighRdy
    
28.     LDRB    R2, [R1]
    
29.     STRB    R2, [R0]
    
30. 
    
31.     LDR     R0, =OSTCBCur                       ; OSTCBCur  = OSTCBHighRdy;
    
32.     LDR     R1, =OSTCBHighRdy
    
33.     LDR     R2, [R1]
    
34.     STR     R2, [R0]
    
35.    
    
36.     LDR     R0, [R2]                            ; R0 is new process SP; SP = OSTCBHighRdy->OSTCBStkPtr;
    
37.     ADDS    R0, #0x10                           ; Adjust SP to High Registers(R8-R11) location
    
38.     LDM     R0!, {R4-R7}                        ; Load R8-R11 values from new process stack into R4-R7
    
39.     MOV     R8,  R4                             ; Restore R8-R11 by moving their values from R4-R7
    
40.     MOV     R9,  R5
    
41.     MOV     R10, R6
    
42.     MOV     R11, R7
    
43.    
    
44.     MSR     PSP, R0                             ; Load PSP with new process SP
    
45.    
    
46.     SUBS    R0, R0, #0x20                       ; Adjust SP to Low registers(R4-R7) location
    
47.     LDM     R0!, {R4-R7}                        ; Restore remaining R4-R7 from new process stack
    
48. 
    
49.     MOV     R0,  R14
    
50.     MOVS    R1,  #0x04                          ; Immediate move to register
    
51.     ORRS    R0,  R1                             ; Ensure exception return uses process stack
    
52.     MOV     R14, R0
    
53.     CPSIE   I
    
54.     BX      LR                                  ; Exception return will restore remaining context

复制代码

eddia2012

遇到楼主同样问题，谢谢楼上解答。